Batch/EXE die 2 Programme startet und schließt

[ZefX]

Batch/EXE die 2 Programme startet und schließt

Guten Tag zusammen,

ich habe mir eine Batch-Datei geschrieben die mir CS:GO und GameDog (GameDog ist eine Software für Razer Geräte zur Steuerung der Beleuchtung, nettes Spielzeug) öffnet. Klaptt auch prima, aber ich hätte es gerne so, das wenn ich CS schließe sich GameDog auch schließt. Wie macht man das?

Jetziger Script:

@echo off
start "" "G:\Program Files (x86)\GameDog\GameDog.exe"
start "" steam://rungameid/730

 

[Felgenfuzzi]

AW: Batch/EXE die 2 Programme startet und schließt

Versuche es doch mal mit "Taskkill"
Zumindest unter XP hat das gut funktioniert.

(Sorry, etwas kurze Antwort, bin via Handy hier. Eigentlich habe ich Batch-Dateien mal geliebt )

Vielleicht hilft Dir das auch weiter:
Prozesse killen

 

[xActionx]

AW: Batch/EXE die 2 Programme startet und schließt

Ich bin nicht sehr vertraut mit Batch aber du könntest eine Schleife schreiben die immer überprüft ob CS usw. noch laufen oder nicht und sobald das Ergebnis false ergibt oder != true ist machst du einen Taskkill um genannte Prozesse zu beenden.

MFG

 

[ZefX]

AW: Batch/EXE die 2 Programme startet und schließt

Ich bin nicht sehr vertraut mit Batch aber du könntest eine Schleife schreiben die immer überprüft ob CS usw. noch laufen oder nicht und sobald das Ergebnis false ergibt oder != true ist machst du einen Taskkill um genannte Prozesse zu beenden.

Nuja, ich bin kein Profi was das angeht^^ Ich benutze Batch/CMD nur sehr sehr selten wie geht das?

 

[ZefX]

AW: Batch/EXE die 2 Programme startet und schließt

Ahh, hab nochmal gegoogle und das mal so gemacht:

@echo off
start "" "G:\Program Files (x86)\GameDog\GameDog.exe"
start "" steam://rungameid/730
:wait
tasklist | find /i "csgo.exe" >nul
if not %errorlevel%==0 goto wait
taskkill /f /im gamedog.exe
exit

Funktioniert aber nicht. Der schließst GameDog immer sofort wieder, obwohl CS noch läuft...

 

[lowskill]

AW: Batch/EXE die 2 Programme startet und schließt

Versuch es mal damit:

START "" "G:\Program Files (x86)\GameDog\GameDog.exe"
START /WAIT "" "steam://rungameid/730"
TASKKILL /IM GameDog.exe

 

[ZefX]

AW: Batch/EXE die 2 Programme startet und schließt

Hmm, auf diese weise startet GameDog garnicht... Versteh aber nicht warum

 

[lowskill]

AW: Batch/EXE die 2 Programme startet und schließt

Wird vermutlich sofort wieder beendet, da der Steam-Prozess, der CS:GO startet, unmittelbar nach dessen Start wieder beendet wird und das Script somit auch nicht wartet, sondern gleich TASKKILL ausführt.

Das sollte nun funktionieren:

@ECHO OFF


START "" "G:\Program Files (x86)\GameDog\GameDog.exe"
START "" "steam://rungameid/730"


:loop1
PING -n 2 127.0.0.1>nul
TASKLIST /FI "IMAGENAME eq csgo.exe" 2>NUL | find /I /N "csgo.exe">NUL
IF NOT "%ERRORLEVEL%"=="0" GOTO loop1


:loop2
PING -n 2 127.0.0.1>nul
TASKLIST /FI "IMAGENAME eq csgo.exe" 2>NUL | find /I /N "csgo.exe">NUL
IF "%ERRORLEVEL%"=="0" GOTO loop2


TASKKILL /F /IM GameDog.exe

In der ersten Schleife wird so lange gewartet, bis der CS:GO-Prozess läuft. In der Zweiten wird so lange gewartet, bis er beendet wurde.
Der Ping-Befehl bewirkt einfach nur eine Verzögerung von einer Sekunde, damit die Überprüfung etwas Ressourcen-schonender abläuft. Gibt zwar extra Befehle (SLEEP, TIMEOUT), die das gleiche bewirken, aber die stehen nicht auf jedem System zur Verfügung.

 

[ZefX]

AW: Batch/EXE die 2 Programme startet und schließt

Ahhhh, ok. Vielen Dank Es funktioniert Prima!